Koha-clms/members/member-flags.pl

#!/usr/bin/perl

# script to edit a member's flags
# Written by Steve Tonnesen
# July 26, 2002 (my birthday!)

use Modern::Perl;

use CGI        qw ( -utf8 );
use C4::Output qw( output_and_exit_if_error output_and_exit output_html_with_http_headers );
use C4::Auth   qw( get_template_and_user get_all_subpermissions get_user_subpermissions );
use C4::Context;

use Koha::Patron::Categories;
use Koha::Patrons;

my $input = CGI->new;

my $flagsrequired = { permissions => 1 };
my $member        = $input->param('member');
my $patron        = Koha::Patrons->find($member);
unless ($patron) {
    print $input->redirect("/cgi-bin/koha/circ/circulation.pl?borrowernumber=$member");
    exit;
}

my $category_type = $patron->category->category_type;
my $bor           = $patron->unblessed;
if ( $category_type eq 'S' ) {    # FIXME Is this really needed?
    $flagsrequired->{'staffaccess'} = 1;
}
my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
    {
        template_name => "members/member-flags.tt",
        query         => $input,
        type          => "intranet",
        flagsrequired => $flagsrequired,
    }
);

my $logged_in_user = Koha::Patrons->find($loggedinuser);
output_and_exit_if_error(
    $input, $cookie, $template,
    { module => 'members', logged_in_user => $logged_in_user, current_patron => $patron }
);

my %member2;
$member2{'borrowernumber'} = $member;

my $op = $input->param('op') // q{};

if ( $op eq 'cud-newflags' ) {
    my @perms        = $input->multi_param('flag');
    my %bare_modules = ();
    my %sub_perms    = ();

    # Each flag param is either a bare module name (e.g. 'borrowers') or
    # a colon-separated module:subperm pair (e.g. 'tools:edit_calendar').
    foreach my $perm (@perms) {
        if ( $perm !~ /:/ ) {
            $bare_modules{$perm} = 1;
        } else {
            my ( $module, $sub_perm ) = split /:/, $perm, 2;
            push @{ $sub_perms{$module} }, $sub_perm;
        }
    }

    # Build granted hashref: bare module flag wins over subpermissions
    my %granted = %bare_modules;
    foreach my $module ( keys %sub_perms ) {
        next if $granted{$module};    # bare flag already set — skip subperms
        $granted{$module} = { map { $_ => 1 } @{ $sub_perms{$module} } };
    }

    $patron->set_permissions( \%granted );
    print $input->redirect("/cgi-bin/koha/members/moremember.pl?borrowernumber=$member");
    exit;
} else {

    my $accessflags;
    my $dbh = C4::Context->dbh();

    # FIXME This needs to be improved to avoid doing the same query
    my $sth = $dbh->prepare("select bit,flag from userflags");
    $sth->execute;
    while ( my ( $bit, $flag ) = $sth->fetchrow ) {
        if ( $bor->{flags} && $bor->{flags} & 2**$bit ) {
            $accessflags->{$flag} = 1;
        }
    }

    my $all_perms  = get_all_subpermissions();
    my $user_perms = get_user_subpermissions( $bor->{'userid'} );
    $sth = $dbh->prepare("SELECT bit, flag FROM userflags ORDER BY bit");
    $sth->execute;
    my @loop;

    while ( my ( $bit, $flag ) = $sth->fetchrow ) {
        my $checked = '';
        if ( $accessflags->{$flag} ) {
            $checked = 1;
        }

        my %row = (
            bit     => $bit,
            flag    => $flag,
            checked => $checked,
        );

        my @sub_perm_loop = ();
        my $expand_parent = 0;
        if ($checked) {
            if ( exists $all_perms->{$flag} ) {
                $expand_parent = 1;
                foreach my $sub_perm ( sort keys %{ $all_perms->{$flag} } ) {
                    push @sub_perm_loop, {
                        id      => "${flag}_$sub_perm",
                        perm    => "$flag:$sub_perm",
                        code    => $sub_perm,
                        checked => 1
                    };
                }
            }
        } else {
            if ( exists $user_perms->{$flag} ) {
                $expand_parent = 1;

                # put selected ones first
                foreach my $sub_perm ( sort keys %{ $user_perms->{$flag} } ) {
                    push @sub_perm_loop, {
                        id      => "${flag}_$sub_perm",
                        perm    => "$flag:$sub_perm",
                        code    => $sub_perm,
                        checked => 1
                    };
                }
            }

            # then ones not selected
            if ( exists $all_perms->{$flag} ) {
                foreach my $sub_perm ( sort keys %{ $all_perms->{$flag} } ) {
                    push @sub_perm_loop, {
                        id      => "${flag}_$sub_perm",
                        perm    => "$flag:$sub_perm",
                        code    => $sub_perm,
                        checked => 0
                        }
                        unless exists $user_perms->{$flag}
                        and exists $user_perms->{$flag}->{$sub_perm};
                }
            }
        }
        $row{expand} = $expand_parent;
        if ( $#sub_perm_loop > -1 ) {
            $row{sub_perm_loop} = \@sub_perm_loop;
        }
        next if ( ( $row{flag} eq 'cash_management' ) && !C4::Context->preference('UseCashRegisters') );
        push @loop, \%row;
    }

    $template->param(
        patron                       => $patron,
        loop                         => \@loop,
        disable_superlibrarian_privs => C4::Context->preference('ProtectSuperlibrarianPrivileges')
        ? !C4::Context->IsSuperLibrarian
        : 0,
    );

    output_html_with_http_headers $input, $cookie, $template->output;
}