Bug 21890: Add Koha::Patron::Category->effective_reset_password method

This method checks wether the local $self->reset_password is set to
override the OpacResetPassword syspref (i.e. if it is set to a bool) or
undef, in which case if falls back to the value of the syspref.

To test:
- Apply this patches
- Make sure the DB is updated:
  $ updatedatabase
- Update the schema files:
  $ dbic
- Run:
  $ kshell
 k$ prove t/db_dependent/Koha/Patron/Category.t
=> SUCCESS: Tests pass!
- Sign off :-D

Signed-off-by: Liz Rea <wizzyrea@gmail.com>
Signed-off-by: Martin Renvoize <martin.renvoize@ptfs-europe.com>

Signed-off-by: Nick Clemens <nick@bywatersolutions.com>

Koha/Patron/Category.pm

@@ -224,6 +224,23 @@ sub get_expiry_date {
     }
 }
 
+=head3 effective_reset_password
+
+Returns if patrons in this category can reset their password. If set in $self->reset_password
+or, if undef, falls back to the OpacResetPassword system preference.
+
+=cut
+
+sub effective_reset_password {
+    my ($self) = @_;
+
+    return ( defined $self->reset_password )
+        ? $self->reset_password
+        : C4::Context->preference('OpacResetPassword');
+}
+
+=head2 Internal methods
+
 =head3 type
 
 =cut

t/db_dependent/Koha/Patron/Category.t

@@ -0,0 +1,88 @@
+#!/usr/bin/perl
+
+# Copyright 2019 Koha Development team
+#
+# This file is part of Koha
+#
+# Koha is free software; you can redistribute it and/or modify it
+# under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 3 of the License, or
+# (at your option) any later version.
+#
+# Koha is distributed in the hope that it will be useful, but
+# WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with Koha; if not, see <http://www.gnu.org/licenses>.
+
+use Modern::Perl;
+
+use Test::More tests => 1;
+
+use t::lib::TestBuilder;
+use t::lib::Mocks;
+
+use Koha::Database;
+
+my $schema  = Koha::Database->new->schema;
+my $builder = t::lib::TestBuilder->new;
+
+subtest 'effective_reset_password() tests' => sub {
+
+    plan tests => 2;
+
+    subtest 'specific overrides global' => sub {
+
+        plan tests => 4;
+
+        $schema->storage->txn_begin;
+
+        my $category = $builder->build_object({
+            class => 'Koha::Patron::Categories',
+            value => {
+                reset_password => 1
+            }
+        });
+
+        t::lib::Mocks::mock_preference( 'OpacResetPassword', 0 );
+        ok( $category->effective_reset_password, 'OpacResetPassword unset, but category has the flag set to 1' );
+
+        t::lib::Mocks::mock_preference( 'OpacResetPassword', 1 );
+        ok( $category->effective_reset_password, 'OpacResetPassword set and category has the flag set to 1' );
+
+        # disable
+        $category->reset_password( 0 )->store->discard_changes;
+
+        t::lib::Mocks::mock_preference( 'OpacResetPassword', 0 );
+        ok( !$category->effective_reset_password, 'OpacResetPassword unset, but category has the flag set to 0' );
+
+        t::lib::Mocks::mock_preference( 'OpacResetPassword', 1 );
+        ok( !$category->effective_reset_password, 'OpacResetPassword set and category has the flag set to 0' );
+
+        $schema->storage->txn_rollback;
+    };
+
+    subtest 'no specific rule, global applies' => sub {
+
+        plan tests => 2;
+
+        $schema->storage->txn_begin;
+
+        my $category = $builder->build_object({
+            class => 'Koha::Patron::Categories',
+            value => {
+                reset_password => undef
+            }
+        });
+
+        t::lib::Mocks::mock_preference( 'OpacResetPassword', 0 );
+        ok( !$category->effective_reset_password, 'OpacResetPassword set to 0 used' );
+
+        t::lib::Mocks::mock_preference( 'OpacResetPassword', 1 );
+        ok( $category->effective_reset_password, 'OpacResetPassword set to 1 used' );
+
+        $schema->storage->txn_rollback;
+    };
+};